For Gauche 0.9.14Search (procedure/syntax/module):

Next: , Previous: , Up: 組み込みライブラリ   [Contents][Index]

6.8 キーワード

Builtin Class: <keyword>

キーワードは、自動的に自分自身に束縛されるシンボルのサブタイプです。 名前つき引数(キーワード引数)や、キーワード-値のリストで広く使われて います。

Gaucheにおけるキーワード引数のサポートについては手続きを作るを、 また独自にキーワード-値リストをパーズする方法については let-keywords マクロ(省略可能引数のパージング) も参照して下さい。

キーワードはかつてはシンボルと独立した型でしたが、それは :で始まる識別子もシンボルとして読まれるR7RSとは非互換でした。 そこで、0.9.5からGaucheは二つのモードを持つようになりました。 キーワードとシンボルが別の型になるモードと、キーワードがシンボルのサブタイプになる モードです。

これらのモードは環境変数によって切り替えられます。 環境変数GAUCHE_KEYWORD_DISJOINTgosh起動時に定義されていたら、 キーワードとシンボルは別の型になります。 そうでなく、環境変数GAUCHE_KEYWORD_IS_SYMBOLが定義されていたら、 キーワードはシンボルのサブタイプになります。

どちらの環境変数も定義されていない場合のデフォルトの動作は、0.9.8で変更になりました。 0.9.7以前はGAUCHE_KEYWORD_DISJOINTの動作がデフォルトですが、 0.9.8以降はGAUCHE_KEYWORD_IS_SYMBOLがデフォルトになっています。

ほとんどの典型的なコードはどちらのモードでも動きますが、 異なる振る舞いをするコードもあります。 二つのモードの違いについてはキーワードとシンボルの統合を参照してください。

将来的に、GAUCHE_KEYWORD_DISJOINTのサポートは無くなる予定です。 今のうちに、現在のデフォルトモードでアプリケーションが走ることを 確認しておくことをお勧めします。

Reader Syntax: :name

名前が :name であるキーワードとして読み込まれます。

Function: keyword? obj

obj がキーワードであれば、#t を返します。

Function: make-keyword name

nameの前に:を付加した名前を持つキーワードを返します。 nameには文字列かシンボルが許されます。

(make-keyword "foo")  ⇒ :foo

(make-keyword 'foo)   ⇒ :foo
Function: keyword->string keyword

キーワード keyword の(先頭の:を除いた)名前を文字列で返します。

(keyword->string :foo) ⇒ "foo"
Function: get-keyword key kv-list :optional fallback

キー-値のリストから値を取り出すのに便利な手続きです。 キー-値のリスト kv-list は偶数個の要素を持たなければなりません。 1つ目、3つ目、5つ目、… の要素はキーとして扱われ、 2つ目、4つ目、6つ目、… の要素は、その前の要素をキーとした値と なります。

この手続きは、キーの集合から key を探して、それが見つかれば、 対応する値を返します。 2つ以上のキーにマッチしたら、最左のものとなります。 マッチするキーがない場合、fallback が与えられていればそれを 返し、さもなければエラーを通知します。

kv-list が正しい偶数個の要素を持つリストでない場合は、エラーに なります。

キーワード-値リストの ‘キーワード’ と、key 引数は、実際には キーワードである必要はありません。いかなる Scheme オブジェクトで あっても良いです。キーの比較は、eq? によって行われます。

この手続きは、STk から導入されました。

(get-keyword :y '(:x 1 :y 2 :z 3))
  ⇒ 2
(get-keyword 'z '(x 1 y 2 z 3))
  ⇒ 3

(get-keyword :t '(:x 1 :y 2 :z 3))
  ⇒ #<error>
(get-keyword :t '(:x 1 :y 2 :z 3) #f)
  ⇒ #f
Macro: get-keyword* key kv-list :optional fallback

get-keyword と同様ですが、kv-listkey を 含まない場合にのみ fallback が評価されることだけが違います。

Function: delete-keyword key kv-list
Function: delete-keyword! key kv-list

kv-list から keyeq? であるキーをもつキーと値を 削除します。

delete-keywordkv-list を変更しません。しかし、 返されたリストは共通の末尾部分を共有します。

delete-keyword! は新しくアロケートされることはありません。 そして、破壊的に kv-list を変更する可能性があります。 最初のキーがマッチした場合元のリストは変更されないこともありえますが、 返り値のリストを使わなければいけません。

key にマッチするキーがない場合 kv-list が返ります。

(delete-keyword :y '(:x 1 :y 2 :z 3 :y 4))
 ⇒ (:x 1 :z 3)
Function: delete-keywords keys kv-list
Function: delete-keywords! keys kv-list

delete-keyworddelete-keyword!と似ていますが、 keysにオブジェクトのリストを指定できます。 kv-list中のキーがkeysのうちのどれかに一致すれば、 そのキーと続く値がkv-listから取り除かれます。

(delete-keywords '(:x :y) '(:x 1 :y 2 :z 3 :y 4))
 ⇒ (:z 3)

6.8.1 キーワードとシンボルの統合

以前のGaucheでは、キーワードはシンボルとは異なる型を持ち、自分自身に評価される オブジェクトでした。 互換性を保つため、現在のGaucheでは:で始まるシンボルは自動的に 自分自身に束縛されるようになっています。

表面的にはこの変更はたいした違いをもたらさないでしょう。 プログラム中に表記してあるキーワードはそれ自身に評価されるので、 かつてと同じようにキーワード引数を渡すことができます。 キーワードを変数として使い、例えば(define :key 3)のように 新たな値に束縛することはできますが、その変更は そうしているモジュールの中だけに留まります。 (他のモジュールはgauche.keywordモジュールにある:keyの束縛を 参照するので影響を受けません。)

けれども、違いが現れるいくつかのわかりづらい場合が存在し、 注意していないと古いコードの互換性を壊してしまうかもしれません。 どちらのモードでも動くようにするコードの書き方をこれから説明します。

新しいモードで問題が出て、コードを直すまで以前の動作で使いたければ、 環境変数GAUCHE_KEYWORD_DISJOINTをセットしてください。

(symbol? :key)は以前は#fを返したが、今は#tを返す

キーワードに対してkeyword?は常に#tを返しますが、 シンボルかキーワードかで動作を変えるコードでは、キーワードの検査を先にするようにしてください。

;; 0.9.7以前は動作が異なる
(cond
  [(symbol? x) (x-is-symbol)]
  [(keyword? x) (x-is-keyword)])

;; どのバージョンでも動く
(cond
  [(keyword? x) (x-is-keyword)]
  [(symbol? x) (x-is-symbol)])

パターンマッチ中のリテラルキーワード

以前のバージョンでは、util.matchsyntax-rulesの パターンにキーワードが現れた場合、それはキーワード自身とのみマッチしました。 現在のバージョンでは、キーワードはシンボルなので、パターン変数として扱われます。

;; 以前のバージョン
(match '(a b) [(:key z) (list :key z)] [_ "nope"])
   ⇒ "nope"

;; 現在のバージョン
;; :keyは単なるパターン変数となる
(match '(a b) [(:key z) (list :key z)] [_ "nope"])
   ⇒ (a b)

syntax-rulesでも同じことが起きます。

どのバージョンでも動くコードにするには、マッチさせたいキーワードが リテラルであることを明示してください。

Gauche 0.9.5から、matchはパターンにクオートされていないキーワードが 現れると警告を発します。

キーワードの表示

(display :key)は以前はkey(コロン無し)を表示しましたが、 現在は:keyを表示します。

keyを表示したい場合は(display (keyword->string :key))とすれば、 どのバージョンでも同じように動作します。

R7RSコードではクオートするかGaucheのモジュールをインポートする

キーワード(:で始まるシンボル)はgauche.keywordモジュール の中で自分自身に束縛されます。

Gaucheコードはデフォルトでgaucheモジュールを継承し、 それがkeywordモジュールを継承しているので、 キーワードの束縛は自動的に見えるようになります。

しかしR7RSコードではgaucheモジュールは継承されないので、 :で始まるシンボルもデフォルトではただのシンボルです。 通常、Gaucheの組み込み機能を使うには(import (gauche base))としますが、 こうするとキーワードの自分自身への束縛もインポートされるようになっています (gauche.basegauche.keywordも継承しているからです)。 ただ、Gaucheの手続きとは別にキーワードをR7RSコード中で使いたい場合は 注意してください。自己束縛されているキーワードだけが欲しければ (import (gauche keyword))とする必要がありますし、 そうしない場合はキーワードに見えるシンボルでもクオートする必要があります。

(import (scheme base))

:foo ⇒ ERROR: unbound variable: :foo

(import (gauche base))

:foo ⇒ :foo

次の例では、R7RSライブラリfoo(gauche base)から copy-portのみをインポートしています。こういった場合、 :sizeキーワードをクオートなしで使うには、(gauche keyword)も 別にインポートしなければなりません。 (あるいは、(gauche base)からインポートするシンボルのリストに :sizeも明示するか)。

(define-library (foo)
  (import (scheme base)
          (only (gauche base) copy-port)
          (gauche keyword))
  (export cat)

  (begin
    (define (cat)
      (copy-port (current-input-port)
                 (current-output-port)
                 :size 4096))))

Next: , Previous: , Up: 組み込みライブラリ   [Contents][Index]


For Gauche 0.9.14Search (procedure/syntax/module):